Markierung modifizieren//Modify check mark

Kontrollkästchen und Optionsfelder kommen immer sehr farblos daher.
Dieses Beispiel zeigt, wie man ihnen mehr Farbe und einen anderen Markierungsstil verpasst.

Check boxes and radio buttons are by default very colorless.
This sample demonstrates how you can give them more color and different check mark styles.

Beispiel
//
Sample
https://files.acrobat.com/a/preview/786f55fc-242d-460a-badf-12b80a6e28db

Individuelle Masterseiten-Zähler//Individual Master Page Counter

Immer wieder fragen Anwender, wie man in einem XFA-Formulare für jede Masterseite einen eigenen Seitenzähler anlegen kann.
Die üblichen Methoden wie xfa.layout.page(this) oder xfa.layout.pageCount() helfen hier nicht weiter.

Die Lösung ist dennoch simpel.
Eine Masterseite hat wie jedes andere Objekt auch eine Indexnummer, beginnend bei 0 für die erste Instanz.
Auf jeder Seite, auf der diese Masterseite erneut auftritt, erhöht sich die Indexnummer um 1.

Platziert man nun ein Feld auf der Masterseite, kann man den Index der Masterseite einfach per Skript im layoutReady-Event fragen.

In FormCalc sieht das dann so aus:

$ = $.parent.index + 1

In JavaScript entsprechend so:

this.rawValue = this.parent.index + 1;

Um nun noch die Gesamtzahl aller Instanzen der Masterseite zu erhalten, zählt man einfach das auftreten der Masterseiten.
Dafür bietet sich die resolveNodes()-Methode an.

In FormCalc:

$ = xfa.resolveNodes(somExpression).length

In JavaScript:

this.rawValue = xfa.resolveNodes(somExpression).length;

Users frequently ask how to create individual page counts for each master page in a XFA form.
The common methods like xfa.layout.page(this) or xfa.layout.pageCount() don't help here.

The solution however is very simple:
As any object a master page has a index number for each occurence, which always begins at 0 for the first instance.
On each page the master page occurs again the index is increased by 1.

If you place a field on your master page you can determine its index easily with a script in the layoutReady Event.

In FormCalc it looks this way:

$ = $.parent.index + 1

In JavaScript that way:

this.rawValue = this.parent.index + 1;

Now you only need to determine how often the master page occurs.
Therefore you can use the resolveNodes() method, as it allows us to count repeatable objects.

In FormCalc:

$ = xfa.resolveNodes(somExpression).length

In JavaScript:

this.rawValue = xfa.resolveNodes(somExpression).length;

Beispiel-Formular
//
Sample form
https://files.acrobat.com/preview/99815d28-441f-47e4-a05b-88e478187157

 

Standard-Funktionen im Skript-Editor anpassen//Modify default functions in script editor

Skripten im Designer erfordert viel Tipparbeit.
Das kann lästig sein, vor allem wenn man immer wieder dieselben Funktionen eintippt.
Von Haus aus hat Designer eine Funktion zum Erleichtern der Tipparbeit, allerdings nur spärlich ausgestattet mit einer Handvoll Funktionen.
Das ist aber kein Problem, ein Text-Editor reicht hier als Problemlöser.

Scripting requires a lot of typing work.
And it can be tedious to type the same functions over and over again.
Designer inherently already has a function to simplfy typing works, but it only offers a handful of functions.
That's not a problem, all you need is a text editor.



Standardmäßige Funktionen-Auswahl im Script-Editor (fn-Schaltfläche)
//
Default function-list in the script editor (fn-Button)

Funktionen-Auswahl im Script-Editor anpassen
//
Edit function-list in the script editor



Schritt 1 – Die Dateien "FormCalc_fn.ini" und "javaScript_fn.ini" im cfg-Ordner des Designers suchen (z.B. C:\Program Files (x86)\Adobe\Adobe LiveCycle Designer ES3\cfg) und kopieren.
//
Step 1 – Look for the files "FormCalc_fn.ini" and "javaScript_fn.ini" in the cfg-folder of Designer ( such as C:\Program Files (x86)\Adobe\Adobe LiveCycle Designer ES3\cfg) and copy them.

Schritt 2 – Kopierte Dateien in einem Text-Editor öffnen und nach Belieben weitere Funktionen oder Skripte hinzufügen.
ACHTUNG: Die Funktionen/Skripte dürfen nur einzeilig sein!
//
Step 2 – Open the copied files in a text editor and add any function or script you like.
ATTENTION: The added functions/script must be single-spaced.

Schritt 3 – Die veränderten Dateien zurück in den cfg-Ordner kopieren, um die alten Dateien zu überschreiben.
//
Step 3 – Copy the modified files back into the cfg folder to replace the old files.






Schritt 4 – Die geänderten Funktionen stehen sofort im Skript-Editor zur Verfügung. Ein Neustart des Designers ist nicht erforderlich.
//
Step 4 – All new functions are immediately available in the script editor. No need to restart Designer.

Alle FormCalc-Funktionen
//
All FormCalc-Functions
https://files.acrobat.com/preview/22f94e45-fb99-4552-9498-cf7100882b46

Alle JavaScript-Funktionen
//
All JavaScript functions
https://files.acrobat.com/preview/d13649a8-d4dd-446a-81b5-fb20c3dfa1be

XFA Apfelmännchen//XFA Mandelbrot Set

Heute gibt's mal was Experimentelles – ein Apfelmännchen in einem XFA-Formular.
Ich wollte immer schon mal wissen, ob das möglich ist, und es ist möglich.

Das Formular berechnet anhand verschiedener Variablen (Pixelanzahl, Pixelgröße, Iterationen usw.) ein Apfelmännchen entweder durch JavaScript oder FormCalc.
Je höher die Werte sind, desto länger dauert die Berechnung dabei.
Zudem steigt der Bedarf an Arbeitsspeicher drastisch.
Da Acrobat und Reader noch immer nicht 64 Bit-fähig sind, müssen sie echt aufpassen, nicht zu große Werte zu verwenden, den bei ca. 3.7GB ist Schluss bei Acrobat und Reader, dann gibt nur noch eine Fehlermeldung und die Anwendung stürzt ab.

ACHTUNG:
Diese Datei sollten sie nur verwenden, wenn sie mindestens 4GB RAM installiert haben.
Acrobat & Reader können während der Berechnung nicht anderweitig verwendet werden.
Wenn Sie die Datei mit dem Apfelmännchen mit großen Werten (> 400x400 Px) speichern, versuchen besser nicht, die Datei anschließend in Designer zu öffnen.

Today something very experimental – a mandelbrot set in a XFA form.
I always wanted to know if it will be possible. It is.

The form calculates the mandelbrot set by reference to several variables (amount of pixels, pixel size, iterations etc.) either with JavaScript or FormCalc.
The higher the values the longer the time for the calculation.
In addition, the memory usage can raise extremely.
As Acrobat and Reader are still not supporting 64 Bit you have to be very carefully with higher values.
If the app needs more than about 3.7GB memory it will show a error message and crash!

ATTENTION:
You should use this file only if you have at least 4 GB RAM installed.
Acrobat & Reader cannot be used otherwise during the calculation.
If you save the file with a mandelbrot with high values (< 400x400 px), you better don't try to open it in Designer again.


Beispiel 1 – Auflösung: 100x100 Px, Iterationen: 5, 10, 30 oder 100, RAM: ~ 125 MB, Dauer: ~ 15 Sekunden
//
Example 1 – resolution: 100x100 px, iterations: 5, 10, 30 or 100, RAM: ~ 125 MB, duration: ~ 15 seconds

Beispiel 2 – Auflösung: 400x400 Px, Iterationen: 5, 10, 30 oder 100, RAM: ~ 635 MB, Dauer: ~ 3 Minuten

//

Example 2 – resolution: 400x400 px, iterations: 5, 10, 30 or 100, RAM: ~ 635 MB, duration: ~ 3 minutes

Beispiel 3 – Auflösung: 800x800 Px, Iterationen: 300, RAM: ~ 2,24 GB, Dauer: ~ 23 Minuten

//

Example 3 – resolution: 800x800 px, iterations: 300, RAM: ~ 2,24 GB, duration: ~ 23 minutes

Beispiel-Formular
//
Example form
https://acrobat.com/#d=7FHS5kHIk0VMXyyQEhCGKg

AKTUALISIERUNG: Die neue Version erlaubt zahlreiche Manipulationen des ursprünglichen Algorithmus, durch sich nun verschiedenste Fraktale erstellen lassen.

UPDATE: The new version allows several manipulations to the initially algorithm, by which you now can create very different fractals.

Beispiel 4 – Auflösung: 400x400 Px, Iterationen: 100, RAM: ~ 635 MB, Dauer: ~ 3 Minuten
Verschiedene Fraktale – nur durch kleine Modifikationen am ursprünglichen Algorithmus erzeugt

//

Example 4 – resolution: 400x400 px, iterations: 100, RAM: ~ 635 MB, duration: ~ 3 minutes

Several different fractals – create only by little modification to the initally algorithm

Beispiel-Formular – V2

//

Example form – V2

https://acrobat.com/#d=-Dp2E2DdAueNCrVxmKWRTQ

XFA Terminkalender//XFA Appointment Calendar

Heute will ich mal zeigen, was man alles mit XFA-Formularen und FormCalc realisieren kann. Dieses Beispiel ist ein Terminkalender.

Wenn Sie ein Jahr auswählen werden sämtliche Monate, Wochen und Tage durch ein Skript berechnet und der Kalender gerendert.
Allerdings ist dieser Vorgangs sehr rechenintensiv und dauert je nach Rechenleistung auch mal eine Minute und länger.

Besonderheiten:
In diesem Beispiel werden die Wochenenden ausgenommen, da man da gewöhnlich nicht arbeitet.
Zeiten bei denen eine Notiz oder ein Termin hinterlegt wurden, werden automatisch durch eine Farbe hervorgehoben.
Des Weiteren wird auch der heutige Tag wird in der Kopfzeile hervorgehoben.

Today I like to show what is possible with XFA forms and FormCalc. This example is an appointment calender.

If you select a year a script starts to calculate all months, week and days in front of rendering the calendar.
But, this progress need thousands of calculations and takes about a minute or longer to finish, depending on the computing power.

Features:
In the example all weekends are excluded because you generally do not work on this days.
Timeslots where a note or appointment has been added are automatically highlighted by a color.
Also, the current date is highlighted in the headline.

Kalender // Calendar

FormCalc-Skript - Berechnung der Kalenderblätter
//
FormCalc script - Calculation of the Calendar Sheets

if (RenderForm.value eq 1) then
    var nPages = Page.instanceManager.count 
    var nStart
    var nLength
    var nIndex
    var nDayNumber
    var nDayName 
    var nWeekDay
    var nWeekNumber
    var nYear = Year
    var nBegin
    var nFirstDay
    var nLastDay
    var nAddDay
    var nCheck

 for p = 0 upto nPages - 1 step 1 do
    nBegin = Concat("1.", p+1, ".", nYear)
    nFirstDay = Date2Num(nBegin, "D.M.YYYY")
    nAddDay = nFirstDay


    for d = 0 upto 31 step 1 do
        nAddDay = nAddDay + 1
        nCheck = Num2Date(nAddDay, "M")
        if (nCheck eq p+1) then
            nLastDay = nAddDay
        endif
    endfor

    nLength = Num2Date(nLastDay, "D")
    Page[p].Head.Month = Num2Date(Date2Num(nBegin, "D.M.YYYY"), "MMMM")
    Page[p].Body._Day.setInstances(nLength)
    nStart = Date2Num(nBegin, "D.M.YYYY")

    for d = 0 upto nLength - 1 step 1 do 
        nIndex = Sum(nStart, d)
        nDayNumber = Num2Date(nIndex, "DD")
        nDayName = Num2Date(nIndex, "EEE")
        nWeekDay = Num2Date(nIndex, "E")
        nWeekNumber = Num2Date(nIndex, "WW")
        if(nWeekDay eq "1" or nWeekDay eq "7") then
            Page[p].Body.Day[d].DayName.Text.w = S_S.value
            Page[p].Body.Day[d].DayName.Text.border.fill.color.value = "128,128,128"
            Page[p].Body.Day[d].Week.Text.w = S_S.value
            Page[p].Body.Day[d].Detail[*].Notes.w = S_S.value
            Page[p].Body.Day[d].Detail[*].Notes.ui.textEdit.border.fill.color.value = "128,128,128"
            Page[p].Body.Day[d].Detail[*].Notes.margin.topInset = "0.0mm"
            Page[p].Body.Day[d].Detail[*].Notes.margin.bottomInset = "0.0mm"
            Page[p].Body.Day[d].Detail[*].Notes.margin.leftInset = "0.0mm"
            Page[p].Body.Day[d].Detail[*].Notes.margin.rightInset = "0.0mm"
            Page[p].Body.Day[d].DayName.Text.value.text.value = ""
            Page[p].Body.Day[d].Week.Text.value.text.value = ""
        else
            Page[p].Body.Day[d].DayName.Text.w = M_F.value  
            Page[p].Body.Day[d].DayName.Text.border.fill.color.value = "255,255,255"
            Page[p].Body.Day[d].Week.Text.w = M_F.value 
            Page[p].Body.Day[d].Detail[*].Notes.w = M_F.value
            Page[p].Body.Day[d].Detail[*].Notes.ui.textEdit.border.fill.color.value = "255,255,255"
            Page[p].Body.Day[d].Detail[*].Notes.margin.topInset = "0.5mm"
            Page[p].Body.Day[d].Detail[*].Notes.margin.bottomInset = "0.5mm"
            Page[p].Body.Day[d].Detail[*].Notes.margin.leftInset = "0.5mm"
            Page[p].Body.Day[d].Detail[*].Notes.margin.rightInset = "0.5mm"
            Page[p].Body.Day[d].DayName.Text.value.text.value = Concat(nDayNumber, ".\u000a", nDayName)

            if(nWeekDay == "2") then
                Page[p].Body.Day[d].Week.Text.value.text.value = nWeekNumber
            else
                Page[p].Body.Day[d].Week.Text.value.text.value = ""
            endif
        endif
    endfor
endfor
RenderForm.value = 0
endif

Beispiel-Kalender // Example Calendar
https://acrobat.com/#d=YpV-ajdmwMmAXZHUPL1E-g

FormCalc Diagramme Teil 6 - Blasendiagramm//FormCalc Charts Pt.6 - Bubble Chart

Heute gibt's nochmal ein neues Diagramm von mir - das Blasendiagramm (oder auch Scatter Plot genannt).
Es hat wie die vorherigen Beispiele auch die Möglichkeit Werte von 0 bis 10000 darzustellen und sich entsprechend zu skalieren.
Im Unterschied zu den bisherigen Beispielen, wird hier neben der Y-Achse auch die X-Achse dynamisch angepasst.

Zum Darstellen mehrerer Blasen, die sich ggf. auch überlappen können, wird wieder ein positioniertes Layout verwendet, bei dem mittels eines Tricks wieder mehrere Instanzen eines Teilformulars hinzugefügt bzw. gelöscht werden können.

Die Blasen zeigen jeweils den Wert für die Größe aus der Eingabetabelle an, wobei sich die Schriftgröße entsprechend der Blasengröße ändert.

Aktualierung:
Für die Blasengröße kann nun ein Mindestwert (in Zoll) angegeben werden, sodass diese im Diagramm nicht zu klein dargestellt werden.

Once more a new chart from me - the bubble chart (or scatter plot).
Like the previous examples it can display values between 0 and 10000 and scale automatically.
The diffrence in this example is, that it can dynamically adapt both, the Y and X-axis.

To display multiple bubbles which possibly can overlay each other, we use a positioned layout, where we can add or remove instances of subforms with a trick.

Each bubble shows the value of the size from the input table, where the font size changes analog to the bubble size.

Update:
For the bubble size you now can define a minimum value (inch size), so the bubble don't get rendered to small in the chart.


FormCalc-Skript – Aktualisierte Version 1.2
//
FormCalc script – Updated version 1.2

func Render(Flag) do
 if (Flag eq "true") then 
  var FactorX  
  var FactorY  
  var FactorS  
  var MaxInputX = Max(Input.Table.ChartValues[*].AmountX)
  var MaxInputY = Max(Input.Table.ChartValues[*].AmountY)
  var MaxInputS = Max(Input.Table.ChartValues[*].AmountS)
  var Fmin
  var FmaxX
  var FmaxY
  var FmaxS
  var MinPlotSize = 0.10 
  var Control = "Plotsizes:"
 
  for Fmin = 0 upto 9950 step 50 do
   FmaxX = Fmin + 50
   if (Within(MaxInputX, Fmin, FmaxX) eq 1) then
    FactorX = 1 / (FmaxX / 100)
   endif
   FmaxY = Fmin + 50
   if (Within(MaxInputY, Fmin, FmaxY) eq 1) then
    FactorY = 1 / (FmaxY / 100)
   endif
   FmaxS = Fmin + 50
   if (Within(MaxInputS, Fmin, FmaxS) eq 1) then
    FactorS = 1 / (FmaxS / 100)
   endif
  endfor
 
  var nRows = Input.Table.ChartValues.instanceManager.count 

  var GraphLabel   
  var ContainerHeight  
  var ContainerWidth   
  var ValueX
  var ValueY
  var ValueS
  var OffsetX
  var OffsetY
  var PlotSize
 
  for r=0 upto nRows -1 step 1 do
   Chart.layout = "tb"
   Chart._Plot.setInstances(nRows)
   Chart._Label.setInstances(nRows)
   Chart.layout = "position"
   ContainerHeight = UnitValue(Chart.Raster.h, "in")
   ContainerWidth = UnitValue(Chart.Raster.w, "in")
   Chart.Plot[r].y = ContainerHeight  
    
   ValueX = Input.Table.ChartValues[r].AmountX
   ValueY = Input.Table.ChartValues[r].AmountY
   ValueS = Input.Table.ChartValues[r].AmountS
   Chart.Plot[r].presence = "visible"
   Chart.Label[r].presence = "visible"

   for x = 0 upto 9 step 1 do
    Output.Chart.xAxis.Mark[x].Mark.value.text.value = Round((1 + x) * 10 / FactorX)
    Output.Chart.xAxis.y = ContainerHeight 
   endfor 
   for y = 10 downto 0 step 1 do
    Output.yAxis.Mark[y].Mark.value.text.value = Round((10 - y) * 10 / FactorY)
   endfor 

   var nColor = Choose(r+1,     
        "238,0,0",   
        "255,99,71", 
        "255,127,80",  
        "255,140,0",  
        "255,165,0",  
        "255,215,0", 
        "255,255,0",  
        "238,238,0",  
        "154,205,50",  
        "69,139,0",  
        "0,139,0",  
        "0,139,69",  
        "69,139,116",
        "82,139,139", 
        "0,139,139", 
        "0,134,139", 
        "83,134,139",
        "102,139,139", 
        "104,131,139", 
        "108,123,139") 

   Chart.Plot[r].Bubble.value.arc.edge.color.value = nColor
   Chart.Plot[r].Bubble.value.arc.fill.color.value = nColor
   Input.Table.ChartValues[r].Color.value.rectangle.fill.color.value = nColor
   GraphLabel = Input.Table.ChartValues[r].Label
   Chart.Label[r].BubbleValue.assist.toolTip.value = GraphLabel

   PlotSize = (ValueS / 150) * FactorS
   if (PlotSize >= MinPlotSize) then
    Chart.Plot[r].Bubble.h =  PlotSize
    Chart.Plot[r].Bubble.w =  PlotSize 
    Chart.Label[r].BubbleValue.h =  PlotSize
    Chart.Label[r].BubbleValue.w =  PlotSize 
   else 
    Chart.Plot[r].Bubble.h = MinPlotSize
    Chart.Plot[r].Bubble.w = MinPlotSize
    Chart.Label[r].BubbleValue.h = MinPlotSize
    Chart.Label[r].BubbleValue.w = MinPlotSize
   endif
   
   OffsetX = UnitValue(ValueX, "in") / 25.4 * FactorX  
   OffsetY = ContainerHeight - UnitValue(ValueY, "in") / 25.4 * FactorY 

   Chart.Plot[r].x =  OffsetX 
   Chart.Plot[r].y =  OffsetY 
   Chart.Label[r].x = OffsetX 
   Chart.Label[r].y = OffsetY 
   
   Chart.Label[r].BubbleValue.value.text.value = ValueS
  endfor

 endif
 RenderChart.value = "false" 
endfunc

Render(RenderChart.value)

Blasendiagramm - mit automatischer Skalierung
//
Bubble chart - with automatic scaling

Beispiel-Formular
//
Example form
https://workspaces.acrobat.com/app.html#d=71mOKqbTBCQOGuBLaSBndg

FormCalc Diagramme Teil 4-V2 - Liniendiagramm//FormCalc Chart Pt.4-V2 - Line Charts

Liniendiagramme sind alles andere als einfach in Designer herzustellen, aber dass es geht habe ich ja schon vor einiger Zeit gezeigt.
Die Version hatte allerdings einige Einschränkungen.
So mussten alle möglicherweise genutzten Liniem schon während der Design-Phase eingefügt werden, da es nur mit einem positionierten Layout möglich ist, Element übereinander zu legen.
Mittels eines Tricks ist das nun nicht mehr nötig.
Dafür genügen schon 4 Zeilen Code.
Kurz gesagt, sagen wir dem Formular erst, dass das Teilformular "Chart" fließend ist, was uns ermöglich von den eingeschlossenen Teilformulare "Line" und "Label" neue Instanzen anzulegen.
Dannach wird das Teilformular einfach wieder auf positioniert gesetzt, fertig.

Chart[j].layout = "tb"
Chart[j]._Line.setInstances(nRows)
Chart[j]._Label.setInstances(nRows)
Chart[j].layout = "position"

Des Weiteren ist das Diagramm auch nicht mehr auf einen kleine Darstellungsbereich beschränkt.
Mittels eines Faktors kann es Werte zwischen 0 und 10.000 dynamisch darstellen.

Line Charts aren't easy to realize in Designer, but a while ago I showed that it is still possible.
Well that version hat some restrictions.
One was, that all possibly used lines already had to added in the design phase, because only a positioned layout allows to lay element on top of each other.
With a small trick this isn't neccessary anymore.
Four lines of code are enough to do this.
In short, we tell the form that the subform "Chart" is flowing, which allows us to add more instances of the wrapped subforms "Line" und "Label".
After that, we reset the subform to positioned, done!

Chart[j].layout = "tb"

Chart[j]._Line.setInstances(nRows)

Chart[j]._Label.setInstances(nRows)

Chart[j].layout = "position"

Aditionally it is now possible to use the chart in a large value range.
With the use of a factor ist can display values between 0 and 10.000 dynamically.

Alte Hierarchie des Formulars - Jedes eventuell benötigte Objekt muss bereits vorhanden sein

//

Old hierarchy of the form - Every possibly needed object has to be already present

Neue Hierarchie des Formulars - Jedes Objekt ist erstmal nur einmalig vorhanden
//
New hierarchy of the form - Every object initially occurs only once

Neues FormCalc-Skript

//

New FormCalc script

var Check = RenderChart.value

if (Check eq "true") then
var Factor
var MaxInput = Max(Input.Table.ChartValues[*].Col[*].Amount)
var Fmin
var Fmax
for f = 0 upto 9950 step 50 do
Fmin = f
Fmax = Fmin + 50
if (Within(MaxInput, Fmin, Fmax) eq 1) then
Factor = 1 / (Fmax / 100)
endif
endfor

var nRows = Input.Table.ChartValues.instanceManager.count
var nColumns = Input.Table.ChartValues[nRows -1].Col.instanceManager.count
_Chart.setInstances(nColumns + 1)

var GraphValue
var GraphLabel
var PrevGraphValue
var GraphDiff
var LineStart
var ContainerHeight
var Offset

for r=0 upto nRows -1 step 1 do
for c=0 upto nColumns -1 step 1 do
Chart[c].layout = "tb"
Chart[c]._Line.setInstances(nRows)
Chart[c]._Label.setInstances(nRows)
Chart[c].layout = "position"
ContainerHeight = UnitValue(Chart[c].hLines.h, "in")
Chart[c].Line[r].y = ContainerHeight
GraphValue = Input.Table.ChartValues[r].Col[c].Amount
Chart[c].Line[r].presence = "visible"
Chart[c].Label[r].presence = "visible"
Chart[0].Line[r].presence = "invisible"

if(c eq 0) then
PrevGraphValue = 0
LineStart = ContainerHeight
else
PrevGraphValue = Input.Table.ChartValues[r].Col[c-1].Amount
LineStart = UnitValue(Chart[c-1].Line.LineGraph.y, "mm")
endif

for y = 10 downto 0 step 1 do
Output.yAxis.Mark[y].Mark.value.text.value = Round((10 - y) * 10 / Factor)
endfor

var nColor = Choose(r+1, ;Instance (+1) = position in this list
"238,0,0", ;Red
"255,99,71", ;Tomato
"255,127,80", ;Coral
"255,140,0", ;DarkOrange
"255,165,0", ;Orange
"255,215,0", ;Gold
"255,255,0", ;Yellow
"238,238,0", ;Yellow2
"154,205,50", ;YellowGreen
"69,139,0", ;Chartreuse
"0,139,0", ;Green
"0,139,69", ;SpringGreen
"69,139,116", ;Aquamarine
"82,139,139", ;DarkSlateGray
"0,139,139", ;Cyan
"0,134,139") ;Turquoise
Chart[c].Line[r].LineGraph.value.line.edge.color.value = nColor
Input.Table.ChartValues[r].Color.Color.value.rectangle.fill.color.value = nColor

GraphDiff = GraphValue - PrevGraphValue
Chart[c].Line[r].LineGraph.h = UnitValue(Abs(GraphDiff), "in") / 25.4 * Factor
Chart[c].Label[r].LineValue.value.text.value = GraphValue
GraphLabel = Input.Table.ChartValues[r].Label
Chart[c].Label[r].LineValue.assist.toolTip.value = GraphLabel

if(GraphDiff >= 0) then
Chart[c].Line[r].LineGraph.value.#line.slope = "/"
else
Chart[c].Line[r].LineGraph.value.#line.slope = "\"
endif

if(c eq 0) then
Offset = ContainerHeight - UnitValue(Abs(GraphDiff), "in") / 25.4 * Factor
Chart[c].Line[r].y = Offset
Chart[c].Label[r].y = Offset
else
if(GraphDiff >= 0) then
Offset = ContainerHeight - GraphValue / 25.4 * Factor
Chart[c].Line[r].y = Offset
Chart[c].Label[r].y = Offset
else
Offset = ContainerHeight - (GraphValue + Abs(GraphDiff)) / 25.4 * Factor
Chart[c].Line[r].y = Offset
Chart[c].Label[r].y = ContainerHeight - (GraphValue / 25.4) * Factor
endif
endif
endfor
endfor
endif
RenderChart.value = "false"

Liniendiagramm - mit automatischer Größenanpassung
//
Line chart - with auto-resizing

Beispiel // Example
https://files.acrobat.com/a/preview/a3e6c8e5-5311-4219-a6f7-d7a2f2259d50

FormCalc Diagramme Teil 5 - Automatisch vergrößerndes, gestapeltes Säulendiagramm//FormCalc Charts Pt.5 - Auto-resizing, stacked Bar Charts

Dies ist eine Weiterentwicklung von dem gestapelten Säulendiagramm, dass ich vor einiger Zeit geposted habe.
Bei dem alten Beispiel störte mich die Beschränkung auf einen bestimmten Wertebereich.
War dieser nicht ausreichend groß dimensioniert, wuchs das Diagramm mitunter oben aus dem Darstellungsbereich heraus.

Mit einer kleinen Ergänzung im Berechnungsalgoritmus ist dies nun aber kein Problem mehr.

Mittels eines Faktors kann der Wertbereich beliebig groß definiert werden.
Dafür prüft eine For-Schreife, ob das größte aller Gesamtergebnisse innerhalb eines bestimmten Bereichs liegt.
Trifft dies zu, wird dann ein Faktor anhand dieses Wertes berechnet, der später in die Berechnung der Balken einbezogen wird.

Des Weiteren wird eine Formularvariable "RenderChart" verwendet, die verhindert, dass der Trigger das Diagramm auch neu berechnet, wenn gar keine Änderung an den Eingabedaten vorliegt.
Mit einem If-Ausdruck wird das ganze Berechnungsskript umfasst und nur dann ausgeführt, wenn die Formvariable den Wert "true" hat.

This is an upgrade of the stacked bar chart I've posted a while ago.
In this old example I get bothered by the limitation of the range of values.
If it was to small the chart began to grow out of the displaying area.

But, with a small addition to the algorithm I was able to solve this problem.

With the use of a factor the range of values can be as large as you like.
Therefor a for-loop is used, which checks if the largest of all total results is within a specific range.
If so, the factor will be calculated by this value and later reused to calculate the bars.

In addition a form variable "RenderChart" is used to suppress a recalculation of the charts if there has been no changes to the input values.
With an if-expression which surrounds the whole calculation script, the script is only executed if the form variable has the value "true".

FormCalc-Skript
//
FormCalc script:

var Check = RenderChart.value
if (Check eq "true") then
var Factor
var MaxInput = Max(Input.Table.ChartValues[*].Sum)
var Fmin
var Fmax
for f = 0 upto 9950 step 50 do
Fmin = f
Fmax = Fmin + 50
if (Within(MaxInput, Fmin, Fmax) eq 1) then
Factor = 1 / (Fmax / 100)
endif
endfor

var nRows = Input.Table.ChartValues.instanceManager.count
_Chart.setInstances(nRows)
var nColumns = Input.Table.ChartValues[nRows -1].Col.instanceManager.count
Chart[*].Stack._Bar[*].setInstances(nColumns)
Chart[*].Labels._Label[*].setInstances(nColumns)

for i=0 upto nRows -1 step 1 do
for j=0 upto nColumns -1 step 1 do
var BarValue = Input.Table.ChartValues[i].Col[j].Amount
for y = 10 downto 0 step 1 do
Output.yAxis.Mark[y].Mark.value.text.value = Round((10 - y) * 10 / Factor)
endfor

var nColor = Choose( j + 1, ;Instance (+1) = position in this list
"238,0,0", ;Red
;"255,48,48", ;FireBrick
"255,99,71", ;Tomato
"255,127,80", ;Coral
"255,140,0", ;DarkOrange
"255,165,0", ;Orange
"255,215,0", ;Gold
"255,255,0", ;Yellow
;"238,238,0", ;Yellow2
"154,205,50") ;YellowGreen
Chart[i].Stack.Bar[j].BarGraph.value.rectangle.fill.color.value = nColor
Chart[i].Stack.Bar[j].BarGraph.value.rectangle.edge.color.value = nColor

if (BarValue > 0) then
Chart[i].Stack.Bar[j].presence = "visible"
else
Chart[i].Stack.Bar[j].presence = "invisible"
endif

var ChartMod = UnitValue(BarValue, "in") / 25.4
Chart[i].Stack.Bar[j].BarGraph.h = UnitValue(ChartMod, "in") * Factor
Chart[i].Labels.Label[j].BarValue.h = UnitValue(ChartMod, "in") * Factor
Chart[i].Labels.BarTotal = Input.Table.ChartValues[i].Sum
Chart[i].Labels.BarLabel = Input.Table.ChartValues[i].Label

if(BarValue * Factor >= 3) then
Chart[i].Labels.Label[j].BarValue.value.text.value = Input.Table.ChartValues[i].Col[j].Amount
else
Chart[i].Labels.Label[j].BarValue.value.text.value = ""
endif

var ContainerHeight = UnitValue(Chart.h, "in")
var MoveHeight = UnitValue(Input.Table.ChartValues[i].Sum, "in") / 25.4 * Factor
Chart[i].Stack.y = ContainerHeight - MoveHeight
Chart[i].Labels.y = ContainerHeight - MoveHeight - UnitValue("5mm", "in")
endfor
endfor
endif

Beispiele gestapelter Balkendiagramme
//
Stacked Bar Charts Examples

Wertebereich 0 - 150 // Range of values 0 - 150

Wertebereich 0 - 550 // Range of values 0 - 550

Wertebereich 0 - 1300 // Range of values 0 - 1300

Bespiel-Formular
//
Sample form:
https://files.acrobat.com/a/preview/d9eaad0a-fea0-4303-8fd4-74a24fadb6fc

FormCalc Diagramme Teil 4 - Liniendiagramm//FormCalc Charts Pt.4 - Line Chart

Ein Liniendiagramm ist ja der Klassiker schlechthin unter den Diagrammen.
Aber, um dieses Diagramm mit dem LiveCycle Designer herzustellen, ist etwas Aufwand nötig, da sich die Instanzen (sprich Graphen) ja überlagern können müssen.
Mit der Möglichkeit Teilformulare dynamisch hinzuzufügen und zu löschen kommt man hier also nicht weit, da sich die Instanzen in XFA-Formularen nur von links nach rechts oder oben nach unten anordnen.

Also muss hier alles, was evtl. angezeigt werden wird, schon im Formularlayout vorhanden sein.
Den Rest kann dann wieder ein einzelnes FormCalc-Script übernehmen.

The line chart is a real classic.
But, to realize it with LiveCycle Designer you need to expend effort.
That's because all instances (graphs) should be able to overlap each other.
Working with repeating subforms in XFA-forms won't work here, because these are only arraged next to each other from top to buttom or left to right and not on top of each other.

So, everything that could be shown later in the chart has to be in the form layout from the beginning.
The rest than could be done by a single FormCalc script.

FormCalc Script (sorry, sript looks a bit unpretty, because this blog editor has it's own life!):

var nRows = Input.Table.ChartValues.instanceManager.count 

var nColumns = Input.Table.ChartValues[nRows -1].Col.instanceManager.count 

_Chart.setInstances(nColumns)

var GraphValue

var GraphLabel

var PrevGraphValue

var GraphDiff

var GraphMod

var LineStart

var ContainerHeight = UnitValue(Chart.h, "in")

var Offset 

for i=0 upto nRows -1 step 1 do

for j=0 upto nColumns -1 step 1 do

if(j == 0) then

GraphValue = Input.Table.ChartValues[i].Col[j].Amount

PrevGraphValue = 0

LineStart = UnitValue(Chart[j].h, "in")

else

GraphValue = Input.Table.ChartValues[i].Col[j].Amount

PrevGraphValue = Input.Table.ChartValues[i].Col[j-1].Amount

LineStart = UnitValue(Chart[j-1].Line.LineGraph.y, "mm")

endif

Chart[j].Line[i].presence = "visible"

Chart[j].Label[i].presence = "visible"

;Select a color for the lines

var nColor = Choose(i+1,

"238,0,0",

"255,99,71",

"255,127,80",

"255,140,0",

"255,165,0",

"255,215,0",

"255,255,0",

"238,238,0",

"154,205,50",

"69,139,0",

"0,139,0",

"0,139,69",

"69,139,116",

"82,139,139",

"0,139,139",

"0,134,139")

Chart[j].Line[i].LineGraph.value.line.edge.color.value = nColor

Input.Table.ChartValues[i].Color.Color.value.rectangle.fill.color.value = nColor

GraphDiff = GraphValue - PrevGraphValue

Chart[j].Line[i].LineGraph.h = UnitValue(Abs(GraphDiff), "in") / 25.4

Chart[j].Label[i].LineValue.value.text.value = GraphValue

GraphLabel = Input.Table.ChartValues[i].Label

Chart[j].Label[i].LineValue.assist.toolTip.value = GraphLabel

if(GraphDiff >= 0) then

Chart[j].Line[i].LineGraph.value.#line.slope = "/"

else

Chart[j].Line[i].LineGraph.value.#line.slope = "\"

endif

if(j == 0) then

Offset = ContainerHeight - UnitValue(Abs(GraphDiff), "in") / 25.4

Chart[j].Line[i].y =  Offset

Chart[j].Label[i].y = Offset 

else

if(GraphDiff >= 0) then

Offset = ContainerHeight - GraphValue / 25.4

Chart[j].Line[i].y = Offset

Chart[j].Label[i].y = Offset

else

Offset = ContainerHeight - (GraphValue + Abs(GraphDiff)) / 25.4 

Chart[j].Line[i].y = Offset 

Chart[j].Label[i].y = ContainerHeight - (GraphValue / 25.4) 

endif

endif

endfor

endfor

Liniendiagramm // Line Chart:

Bespiel // Example:
https://files.acrobat.com/a/preview/34a5dfb2-392b-41e3-959d-11536d9a9b22